xsl:attribute

Syntax

<xsl:attribute>
     Template-Body
</xsl:attribute>

Postition

innerhalb des Template-Bodys oder innerhalb des <xsl:attribute-set> Elements

Attribute
Bezeichnung Wert Bedeutung
name {QName} Name des Attributs
namespace {uri} Namespace-URI des Attributs

<xsl:attribute>

innerhalb des Template-Bodys:
erzeugt ein Attribut an die aktuelle Position des Output-Dokuments. Die Anweisung ist nur dann erfolgreich, wenn sie unmittelbar nach der Erzeugung eines Elements ausgeführt wird. Der Template-Body der Anweisung bestimmt den zugehörigen Wert des Attributs. Wird das Attribut öfters definiert, wird der Wert der letzten Definition übernommen.

innerhalb des <xsl:attribute-set> Elements:
siehe <xsl:attribute-set>


Definition

XSLT Kapitel 7.1.3

Beispiel

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="html"/>
    
<xsl:template match="/">
     <HTML>
          <HEAD>
               <TITLE>Element: &lt;xsl:attribute&gt; / Beispiel 01</TITLE>
          </HEAD>
          <BODY>
               <xsl:apply-templates select="shop"/>
          </BODY>
     </HTML>
</xsl:template>

<xsl:template match="shop">
     <TABLE BORDER="1">
          <TR>
               <TH WIDTH="150">Artikel:</TH>
               <TH WIDTH="150">Auswahl:</TH>
               <TH WIDTH="100">Preis:</TH>
          </TR>
          <FORM>
               <xsl:apply-templates select="order/product"/>
          </FORM>
     </TABLE>
     <A>
          <xsl:attribute name="HREF">
               <xsl:text>mailto:</xsl:text>
               <xsl:value-of select="/shop/customer/e-mail"/>
          </xsl:attribute>
          <xsl:text>E-Mail</xsl:text>
     </A>
</xsl:template>
    
<xsl:template match="product">
     <TR>
          <TD><xsl:value-of select="name"/></TD>
          <TD ALIGN="RIGHT">
               <xsl:apply-templates select="variation"/>
          </TD>
          <TD ALIGN="RIGHT">
               <xsl:value-of select="price"/>
               <xsl:text> </xsl:text>
               <xsl:value-of select="currency"/>
          </TD>
     </TR>
</xsl:template>
    
<xsl:template match="variation">
     <SELECT ID="Farbe">
          <xsl:for-each select="color">
               <OPTION VALUE="{@name}">
                    <xsl:if test="@selected='true'">
                         <xsl:attribute name="SELECTED">SELECTED</xsl:attribute>
                    </xsl:if>
                    <xsl:value-of select="@name"/>
               </OPTION>
          </xsl:for-each>
     </SELECT>
</xsl:template>

</xsl:stylesheet>

© 2001 by Timo Schäfer