Element: <xsl:decimal-format>

xsl:decimal-format

Syntax

<xsl:decimal-format/>

Postition

Top-Level Element

Attribute

Bezeichnung	Wert	Bedeutung
name	QName	Name des Dezimalformats; falls dieser nicht angegeben wird, beziehen sich die Definitionen auf die allgemeinen Einstellungen
decimal-separator	character	Zeichen, das den ganzzahlingen Teil von dem Bruch trennt; Grundeinstellung: [.]
grouping-separator	character	Zeichen, das eine Gruppe von Ziffern trennt; Grundeinstellung: [,]
infinity	string	String, der den nummerischen Wert für unendlich repräsentiert; Grundeinstellung: [Infinity]
minus-sign	character	Zeichen, das einen negativen Wert kennzeichnet; Grundeinstellung: [-]
NaN	string	String, der einen nicht nummerischen Wert darstellt; Grundeinstellung: [NaN]
percent	character	Zeichen, welches das Prozentzeichen repräsentiert; Grundeinstellung: [%]
per-mille	character	Zeichen, welches das Promillezeichen repräsentiert; Grundeinstellung: [%O]
zero-digit	charcter	Zeichen, das für eine Zahl gebraucht wird, die mit einer Null beginnt; Grundeinstellung: [0]
digit	character	Zeichen, das einen Platzhalter für eine Ziffer darstellt; Grundeinstellung: [#]
pattern-separator	character	Zeichen, das die postive von der negativen Zahlenformatdarstellung trennt; Grundeinstellung: [;]

<xsl:decimal-format>

definiert Zeichen und Symbole, die bei der Konvertierung von Zahlen in Strings verwendet werden sollen. Die Umwandlung erfolgt durch die Funktion format-number( ). Andere Funktionen sind durch die hier vorgenommenen Definitionen nicht betroffen.

Definition

XSLT Kapitel 12.3

Beispiel

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="html"/>

<xsl:decimal-format name="european" decimal-separator="," grouping-separator="."/>

<xsl:template match="/">
     <HTML>
          <HEAD>
               <TITLE>Element: <xsl:decimal-format> / Beispiel 01</TITLE>
          </HEAD>
          <BODY>
               <xsl:apply-templates select="shop"/>
          </BODY>
     </HTML>
</xsl:template>

<xsl:template match="shop">
     <TABLE BORDER="1">
          <TR>
               <TH WIDTH="150">Abteilung:</TH>
               <TH WIDTH="100">Artikel:</TH>
               <TH WIDTH="100">Preis:</TH>
          </TR>
          <xsl:apply-templates select="order/product"/>
     </TABLE>
</xsl:template>

<xsl:template match="product">
     <TR>
          <TD><xsl:value-of select="@department"/></TD>
          <TD><xsl:value-of select="name"/></TD>
          <TD ALIGN="RIGHT">
               <xsl:value-of select="format-number(price, '#.##0,0', 'european')"/>
               <xsl:text> </xsl:text>
               <xsl:value-of select="currency"/>
          </TD>
     </TR>
</xsl:template>

</xsl:stylesheet>