Funktion: boolean()

boolean

Syntax

boolean(value) -> boolean

Argumente

Bezeichnung	Datentyp	Bedeutung
value	beliebig	Wert, der in einen boolesche Wert konvertiert werden soll

boolean( )

konvertiert das übergebene Argument in eine boolesche Variable.

Die Konvertierung unterliegt folgenden Regeln:

Datentyp	Konvertierungsregel
number	Null ergibt "false"; die restlichen Zahlen ergeben "true"
string	String mit der Länge Null ergibt "false"; alles andere "true"
boolean	Wert bleibt unverändert
node-set	leerer Knotenset ergibt "false"; alles andere "true"
result tree fragment	das Fragment des Ergebnisbaums wird zunächst in ein String und schließlich in eine boolesche Variable konvertiert. es liefert "false", wenn es einen leeren Textknoten enthält, ansonsten "true"

Definition

XPath Kapitel 4.3

Beispiel

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="html"/>

<xsl:template match="/">
     <HTML>
          <HEAD>
               <TITLE>Funktion: boolean() / Beispiel 01</TITLE>
          </HEAD>
          <BODY>
               <xsl:apply-templates select="shop"/>
          </BODY>
     </HTML>
</xsl:template>

<xsl:template match="shop">
     <TABLE BORDER="1">
          <TR>
               <TH WIDTH="150">Abteilung:</TH>
               <TH WIDTH="100">Artikel:</TH>
               <TH WIDTH="150">Kommentar:</TH>
               <TH WIDTH="100">Preis:</TH>
          </TR>
          <xsl:apply-templates select="order/product"/>
     </TABLE>
</xsl:template>

<xsl:template match="product">
     <TR>
          <TD><xsl:value-of select="@department"/></TD>
          <TD><xsl:value-of select="name"/></TD>
          <TD>
               <xsl:choose>
                    <xsl:when test="boolean(comment)">
                         <xsl:value-of select="comment"/>
                    </xsl:when>
                    <xsl:otherwise>
                         kein Kommentar verfügbar
                    </xsl:otherwise>
               </xsl:choose>
          </TD>
          <TD ALIGN="RIGHT">
               <xsl:value-of select="price"/>
               <xsl:text> </xsl:text>
               <xsl:value-of select="currency"/>
          </TD>
     </TR>
</xsl:template>

</xsl:stylesheet>