Funktion: contains()

contains

Syntax

contains(value, substring) -> boolean

Argumente

Bezeichnung	Datentyp	Bedeutung
value	string	String, der darauf geprüft wird, ob er den Teilstring enthält; falls es sich bei dem Wert nicht um einen String handelt, wird dieser zunächst nach den Regeln der string( ) Funktion umgewandelt
substring	string	Teilstring; falls es sich bei dem Wert nicht um einen String handelt, wird dieser zunächst nach den Regeln der string( ) Funktion umgewandelt

contains( )

prüft, ob ein String einen bestimmten Teilstring enthält. Sollte dieser enthalten sein, ist der Rückgabewert "true", im anderen Falle "false". Ist der Teilstring leer, dann ist das Ergebnis "true". Sofern der String allerdings leer ist, erhält man das Ergebnis "false". Im Falle das auch der Teilstring leer ist, ist das Ergebnis "true".

Definition

XPath Kapitel 4.2

Beispiel

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="html"/>

<xsl:template match="/">
     <HTML>
          <HEAD>
               <TITLE>Funktion: contains() / Beispiel 01</TITLE>
          </HEAD>
          <BODY>
               <xsl:apply-templates select="shop"/>
          </BODY>
     </HTML>
</xsl:template>

<xsl:template match="shop">
     <TABLE BORDER="1">
          <TR>
               <TH WIDTH="150">Abteilung:</TH>
               <TH WIDTH="100">Artikel:</TH>
               <TH WIDTH="100">Preis:</TH>
          </TR>
          <xsl:apply-templates select="order/product"/>
     </TABLE>
     <xsl:value-of select="concat('Kunde: ', customer/name, ' ', customer/surname)"/>
     <BR/>
     <xsl:if test="contains(customer/address, 'Germany')">
          <xsl:text>Land: Deutschland</xsl:text>
     </xsl:if>
</xsl:template>

<xsl:template match="product">
     <TR>
          <TD><xsl:value-of select="@department"/></TD>
          <TD><xsl:value-of select="name"/></TD>
          <TD ALIGN="RIGHT">
               <xsl:value-of select="price"/>
               <xsl:text> </xsl:text>
               <xsl:value-of select="currency"/>
          </TD>
     </TR>
</xsl:template>

</xsl:stylesheet>