Funktion: function-available()

function-available

Syntax

function-available(name) -> boolean

Argumente

Bezeichnung	Datentyp	Bedeutung
name	string	Name der Funktion; falls es sich bei dem Wert nicht um einen String handelt, wird dieser zunächst nach den Regeln der string( ) Funktion umgewandelt

function-available( )

prüft, ob eine spezifische Funktion oder ein erweiterte Funktion verfügbar ist. Ist die Funktion verfügbar, wird der boolesche Wert "true" zurückgegeben, ansonsten "false".

Definition

XSLT Kapitel 15

Beispiel

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="html"/>

<xsl:template match="/">
     <HTML>
          <HEAD>
               <TITLE>Funktion: function-available() / Beispiel 01</TITLE>
          </HEAD>
          <BODY>
               <xsl:apply-templates select="shop"/>
          </BODY>
     </HTML>
</xsl:template>

<xsl:template match="shop">
     <TABLE BORDER="1">
          <TR>
               <TH WIDTH="150">Abteilung:</TH>
               <TH WIDTH="100">Artikel:</TH>
               <TH WIDTH="100">Preis:</TH>
          </TR>
          <xsl:apply-templates select="order/product"/>
          <xsl:if test="not(function-available('currency'))">
               <xsl:comment> Funktion currency() ist nicht verfügbar ! </xsl:comment>
          </xsl:if>
     </TABLE>
</xsl:template>

<xsl:template match="product">
     <TR>
          <TD><xsl:value-of select="@department"/></TD>
          <TD><xsl:value-of select="name"/></TD>
          <TD ALIGN="RIGHT">
               <xsl:value-of select="price"/>
               <xsl:text> </xsl:text>
               <xsl:value-of select="currency"/>
          </TD>
     </TR>
</xsl:template>

</xsl:stylesheet>