Funktion: normalize-space()

normalize-space

Syntax

normalize-space( ) -> string
normalize-space(value) -> string

Argumente

Bezeichnung	Datentyp	Bedeutung
value	String	String; falls es sich bei dem Wert nicht um einen String handelt, wird dieser zunächst nach den Regeln der string( ) Funktion umgewandelt

normalize-space( )

entfernt alle Anfangs- und End-White Spaces des Strings. Eine Sequenz von White Spaces wird durch ein einziges Leerzeichen ersetzt. Wurde das Attribut [value] nicht gesetzt, bezieht sich die Funktion auf die vorhandenen Textknoten.

Definition

XPath Kapitel 4.2

Beispiel

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="html"/>

<xsl:template match="/">
     <HTML>
          <HEAD>
               <TITLE>Funktion: normalize-space() / Beispiel 01</TITLE>
          </HEAD>
          <BODY>
               <xsl:apply-templates select="shop"/>
          </BODY>
     </HTML>
</xsl:template>

<xsl:template match="shop">
     <TABLE BORDER="1">
          <TR>
               <TH WIDTH="150">Abteilung:</TH>
               <TH WIDTH="100">Artikel:</TH>
               <TH WIDTH="100">Preis:</TH>
          </TR>
          <xsl:apply-templates select="order/product"/>
     </TABLE>
     <xsl:value-of select="concat('Kunde: ', customer/name, ' ', customer/surname)"/>
     <BR/>
     <xsl:text>Adresse: </xsl:text>
     <PRE><xsl:value-of select="normalize-space(customer/address)"/></PRE>

</xsl:template>

<xsl:template match="product">
     <TR>
          <TD><xsl:value-of select="@department"/></TD>
          <TD><xsl:value-of select="name"/></TD>
          <TD ALIGN="RIGHT">
               <xsl:value-of select="price"/>
               <xsl:text> </xsl:text>
               <xsl:value-of select="currency"/>
          </TD>
     </TR>
</xsl:template>

</xsl:stylesheet>