Funktion: not()

not

Syntax

not(condition) -> boolean

Argumente

Bezeichnung	Datentyp	Bedeutung
condition	boolean	Bedingung; falls es dabei um keinen boolischen Wert handelt, wird dieser nach den Regeln der boolean( ) Funktion umgewandelt

not( )

gibt den booleschen Wert "true" zurück, wenn die Bedingung "false" ist bzw. den Wert "false", wenn die Bedingung "true" ist.

Definition

XPath Kapitel 4.3

Beispiel

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="html"/>

<xsl:template match="/">
     <HTML>
          <HEAD>
               <TITLE>Funktion: not() / Beispiel 01</TITLE>
          </HEAD>
          <BODY>
               <xsl:apply-templates select="shop"/>
          </BODY>
     </HTML>
</xsl:template>

<xsl:template match="shop">
     <TABLE BORDER="1">
          <TR>
               <TH WIDTH="150">Abteilung:</TH>
               <TH WIDTH="100">Artikel:</TH>
               <TH WIDTH="100">Preis:</TH>
          </TR>
          <xsl:apply-templates select="order/product"/>
     </TABLE>
     <xsl:choose>
          <xsl:when test="not(order/product/price = '60.00')">
               <xsl:text>Es existiert kein Produkt mit dem Preis 60.00 !</xsl:text>
          </xsl:when>
          <xsl:otherwise>
               <xsl:text>Es existiert ein Produkt mit dem Preis 60.00 !</xsl:text>
          </xsl:otherwise>
     </xsl:choose>
     <BR/>
     <xsl:choose>
          <xsl:when test="order/product/price != '60.00'">
               <xsl:text>Es existiert ein Produkt mit dem Preis ungleich 60.00 !</xsl:text>
          </xsl:when>
          <xsl:otherwise>
               <xsl:text>Es existiert kein Produkt mit dem Preis ungleich 60.00 !</xsl:text>
          </xsl:otherwise>
     </xsl:choose>
     <BR/>
     <xsl:choose>
          <xsl:when test="not(order/product/price != '60.00')">
               <xsl:text>Alle Produkte haben einen Preis von 60.00 !</xsl:text>
          </xsl:when>
          <xsl:otherwise>
               <xsl:text>Mindestens ein Produkt hat einen Preis ungleich 60.00 !</xsl:text>
          </xsl:otherwise>
     </xsl:choose>
</xsl:template>

<xsl:template match="product">
     <TR>
          <TD><xsl:value-of select="@department"/></TD>
          <TD><xsl:value-of select="name"/></TD>
          <TD ALIGN="RIGHT">
               <xsl:value-of select="price"/>
               <xsl:text> </xsl:text>
               <xsl:value-of select="currency"/>
          </TD>
     </TR>
</xsl:template>

</xsl:stylesheet>