Funktion: sum()

sum

Syntax

sum(nodes) -> number

Argumente

Bezeichnung	Datentyp	Bedeutung
nodes	node-set	Knotenset, das die aufzusummierenden Knoten enthält; es handelt sich um einen Fehler, wenn es sich dabei um keinen Knotenset handelt

sum( )

berechnet die Summe aller spezifischen Knoten innerhalb eines Knotensets. Sind die einzelnen Knoten des Knotensets vom Datentyp String, werden sie zunächst nach den Regeln der number( ) Funktion in eine Zahl umgewandelt. Erhält ein Knoten, den Wert "NaN", ist das Ergbnis der Funktion auch "NaN". Ist der Knotenset leer, ist das Ergebnis Null.

Definition

XPath Kapitel 4.4

Beispiel

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="html"/>

<xsl:template match="/">
     <HTML>
          <HEAD>
               <TITLE>Funktion: sum() / Beispiel 01</TITLE>
          </HEAD>
          <BODY>
               <xsl:apply-templates select="shop"/>
          </BODY>
     </HTML>
</xsl:template>

<xsl:template match="shop">
     <TABLE BORDER="1">
          <TR>
               <TH WIDTH="100">Artikel:</TH>
               <TH WIDTH="100">Preis:</TH>
               <TH WIDTH="100">Anzahl:</TH>
          </TR>
          <xsl:apply-templates select="order/product"/>
          <TR>
               <TD COLSPAN="3" ALIGN="RIGHT">
                    <xsl:text>Gesamtanzahl der Produkte: </xsl:text>
                    <xsl:value-of select="sum(order/product/amount)"/>
               </TD>
          </TR>
     </TABLE>
</xsl:template>

<xsl:template match="product">
     <TR>
          <TD><xsl:value-of select="name"/></TD>
          <TD ALIGN="RIGHT">
               <xsl:value-of select="price"/>
               <xsl:text> </xsl:text>
               <xsl:value-of select="currency"/>
          </TD>
          <TD ALIGN="RIGHT"><xsl:value-of select="amount"/></TD>
     </TR>
</xsl:template>

</xsl:stylesheet>