Funktion: system-property()

system-property

Syntax

system-property(name) -> any

Argumente

Bezeichnung	Datentyp	Bedeutung
name	string	definiert den Namen der Systemeigenschaft; falls es sich bei dem Wert nicht um einen String handelt, wird dieser zunächst nach den Regeln der string( ) Funktion umgewandelt

system-property( )

liefert Informationen über die Prozessumgebung einer bestimmten Systemeigenschaft. Wenn die angegebene Systemeigenschaft nicht existiert, wird ein leerer String zurückgegeben.

Folgende Systemeigenschaften werden von jedem Prozessor unterstützt:

Systemeigenschaft	Bedeutung
xsl:version	liefert die XSLT-Version, die der Prozessor unterstützt
xsl:vendor	liefert den Namen des Herstellers, der den Prozessor entwickelt hat
xsl:vendor-url	URL des Herstellers

Definition

XSLT Kapitel 12.4

Beispiel

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="html"/>

<xsl:template match="/">
     <HTML>
          <HEAD>
               <TITLE>Funktion: system-property() / Beispiel 01</TITLE>
          </HEAD>
          <BODY>
               <xsl:apply-templates select="shop"/>
          </BODY>
     </HTML>
</xsl:template>

<xsl:template match="shop">
     <TABLE BORDER="1">
          <TR>
               <TH WIDTH="150">Abteilung:</TH>
               <TH WIDTH="100">Artikel:</TH>
               <TH WIDTH="100">Preis:</TH>
          </TR>
          <xsl:apply-templates select="order/product"/>
          <xsl:message>
               Version: <xsl:value-of select="system-property('xsl:version')"/>
               Hersteller: <xsl:value-of select="system-property('xsl:vendor')"/>
               URL: <xsl:value-of select="system-property('xsl:vendor-url')"/>
          </xsl:message>
     </TABLE>
</xsl:template>

<xsl:template match="product">
     <TR>
          <TD><xsl:value-of select="@department"/></TD>
          <TD><xsl:value-of select="name"/></TD>
          <TD ALIGN="RIGHT">
               <xsl:value-of select="price"/>
               <xsl:text> </xsl:text>
               <xsl:value-of select="currency"/>
          </TD>
     </TR>
</xsl:template>

</xsl:stylesheet>