Funktion: translate()

translate

Syntax

translate(value, from, to) -> string

Argumente

Bezeichnung	Datentyp	Bedeutung
value	string	String; falls es sich bei dem Wert nicht um einen String handelt, wird dieser zunächst nach den Regeln der string( ) Funktion umgewandelt
from	string	Liste der Zeichen, die ersetzt werden sollen; falls es sich bei dem Wert nicht um einen String handelt, wird dieser zunächst nach den Regeln der string( ) Funktion umgewandelt
to	string	Liste der Ersetzungszeichen; falls es sich bei dem Wert nicht um einen String handelt, wird dieser zunächst nach den Regeln der string( ) Funktion umgewandelt

translate( )

transformiert den ursprünglichen String in einen Resultatstring. Alle Zeichen, die zu ersetzen sind, werden durch die Ersetzungszeichen substituiert. Die übrigen werden unverändert kopiert. Existiert kein Ersetzungszeichen, wird das ursprüngliche Zeichen gelöscht. Enthält die Liste der zu ersetzenden Zeichen mehrere gleiche Einträge, wird nur die erste Definition angenommen.

Definition

XPath Kapitel 4.2

Beispiel

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:output method="html"/>

<xsl:template match="/">
     <HTML>
          <HEAD>
               <TITLE>Funktion: translate() / Beispiel 01</TITLE>
          </HEAD>
          <BODY>
               <xsl:apply-templates select="shop"/>
          </BODY>
     </HTML>
</xsl:template>

<xsl:template match="shop">
     <TABLE BORDER="1">
          <TR>
               <TH WIDTH="150">Abteilung:</TH>
               <TH WIDTH="100">Artikel:</TH>
               <TH WIDTH="100">Preis:</TH>
          </TR>
          <xsl:apply-templates select="order/product"/>
     </TABLE>
</xsl:template>

<xsl:template match="product">
     <TR>
          <TD><xsl:value-of select="@department"/></TD>
          <TD>
               <xsl:value-of select="translate(name, 'abcdefghijklmnopqrstuvwxyz',
'ABCDEFGHIJKLMNOPQRSTUVWXYZ')"/>
          </TD>
          <TD ALIGN="RIGHT">
               <xsl:value-of select="price"/>
               <xsl:text> </xsl:text>
               <xsl:value-of select="currency"/>
          </TD>
     </TR>
</xsl:template>

</xsl:stylesheet>